agw
56434ba7ed
Bundling R alone was not enough: R links libicuuc, and Arch moves ICU regularly. The obvious fix - pinning 'icu>=78 <79' in depends - is worse than the disease on a rolling distro, because pacman would then refuse to upgrade ICU while JASP is installed, blocking the user's whole system upgrade until a rebuild lands. So bundle-libs.sh copies every non-system shared library into /opt/jasp-desktop/lib and rewrites rpaths, by denylist rather than allowlist. depends now carries no version constraints at all. Qt6 stays system-provided on purpose - Qt is binary compatible across Qt 6 minors, and bundling QtWebEngine would add ~500 MB. That also means the only rebuild triggers left are a new JASP release and a Qt major bump; rebuilding for anything else would cost users a 1.7 GB re-download. Also fixes check-upstream.py querying only repo=Extra, which silently returned nothing for icu (it lives in core).
49 lines
1.9 KiB
Plaintext
49 lines
1.9 KiB
Plaintext
# Maintainer: @MAINTAINER@
|
|
#
|
|
# Upstream JASP publishes installers for Windows and macOS only. The binary this
|
|
# package installs is therefore not an upstream release artifact: it is built
|
|
# from the tagged JASP sources on Arch by
|
|
# https://gitea.weircon.dk/agw/jasp-desktop-bin and published to GitHub Releases.
|
|
|
|
pkgname=jasp-desktop-bin
|
|
pkgver=@JASP_VERSION@
|
|
pkgrel=@PKGREL@
|
|
pkgdesc="JASP Desktop - a fresh way to do statistics (prebuilt binary)"
|
|
arch=('x86_64')
|
|
url="https://jasp-stats.org/"
|
|
license=('AGPL-3.0-or-later')
|
|
|
|
provides=("jasp-desktop=${pkgver}")
|
|
conflicts=('jasp-desktop')
|
|
|
|
# This package ships its own R @BUNDLED_R@ plus the non-system libraries it and
|
|
# the JASP R modules link against (ICU, jsoncpp, glpk, JAGS, readstat, librdata,
|
|
# BLAS/LAPACK ...) under /opt/jasp-desktop/lib, with rpath pointing there.
|
|
#
|
|
# That is deliberate, and it is why nothing below is version-pinned: on a rolling
|
|
# distro a pin like 'icu<79' would make pacman refuse to upgrade ICU while JASP
|
|
# is installed, blocking the user's entire system upgrade. Bundling means JASP
|
|
# never constrains the system.
|
|
#
|
|
# Qt6 is the exception and stays a system dependency: Qt guarantees binary
|
|
# compatibility across Qt 6 minor releases, and bundling QtWebEngine would add
|
|
# ~500 MB for no real gain. A Qt 7 transition will need a rebuild.
|
|
depends=(
|
|
'qt6-base' 'qt6-declarative' 'qt6-svg' 'qt6-positioning' 'qt6-webchannel'
|
|
'qt6-webengine' 'qt6-5compat' 'qt6-httpserver'
|
|
'fontconfig' 'freetype2' 'libxkbcommon' 'hicolor-icon-theme'
|
|
)
|
|
|
|
# The tarball is a complete /opt + /usr install tree. Stripping would be slow and
|
|
# is a good way to break a bundled R plus several hundred compiled R modules;
|
|
# the rpath set at build time must also survive untouched.
|
|
options=('!strip' '!debug')
|
|
|
|
source=("jasp-desktop-${pkgver}-${pkgrel}-x86_64.tar.zst::@DOWNLOAD_URL@")
|
|
sha256sums=('@SHA256@')
|
|
|
|
package() {
|
|
cp -a "${srcdir}/opt" "${pkgdir}/opt"
|
|
cp -a "${srcdir}/usr" "${pkgdir}/usr"
|
|
}
|